UDF > GUI > GuiStatusBar >


_GUICtrlStatusBar_GetHeight

Obtient la hauteur de la barre d'état

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetHeight ( $hWnd )

Paramètre

$hWnd Handle du contrôle StatusBar

Valeur de retour

Retourne la hauteur.

En relation

_GUICtrlStatusBar_GetWidth, _GUICtrlStatusBar_SetMinHeight

Exemple

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; Crée une GUI
    $hGUI = GUICreate("StatusBar Get Height", 400, 300)

    $hStatus = _GUICtrlStatusBar_Create($hGUI)
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient la hauteur et la largeur des parties
    MemoWrite("Height of parts .: " & _GUICtrlStatusBar_GetHeight($hStatus))
    MemoWrite("Width of part 1 .: " & _GUICtrlStatusBar_GetWidth($hStatus, 0))
    MemoWrite("Width of part 2 .: " & _GUICtrlStatusBar_GetWidth($hStatus, 1))
    MemoWrite("Width of part 3 .: " & _GUICtrlStatusBar_GetWidth($hStatus, 2))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite