UDF > GUI > GuiStatusBar >


_GUICtrlStatusBar_GetBorders

Obtient les largeurs actuelles des bordures verticales et horizontales

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetBorders ( $hWnd )

Paramètre

$hWnd Handle du contrôle StatusBar

Valeur de retour

Succès: Retourne un tableau avec le format suivant:
    $aBorders[0] - Largeur de la bordure horizontale
    $aBorders[1] - Largeur de la bordure verticale
    $aBorders[2] - Largeur de la frontière entre les rectangles
Échec: Définit @error <> 0.

En relation

_GUICtrlStatusBar_GetBordersHorz, _GUICtrlStatusBar_GetBordersRect, _GUICtrlStatusBar_GetBordersVert

Exemple

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $aInfo, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; Crée une GUI
    $hGUI = GUICreate("StatusBar Get Borders", 400, 300)

    $hStatus = _GUICtrlStatusBar_Create($hGUI)
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient la taille des bordures
    $aInfo = _GUICtrlStatusBar_GetBorders($hStatus)
    MemoWrite("Horizontal border width .: " & $aInfo[0])
    MemoWrite("Vertical border width ...: " & $aInfo[1])
    MemoWrite("Width between rectangles : " & $aInfo[2])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite