UDF > GUI > GuiRichEdit >


_GUICtrlRichEdit_GetTextLength

Obtient la longueur du texte entier contenu dans le contrôle

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetTextLength ( $hWnd [, $bExact = True [, $bChars = False]] )

Paramètres

$hWnd Handle du contrôle
$bExact [optionnel]
    True - Retourne la longueur exacte
    False - Retourne un minorant du nombre de caractères du contrôle (plus rapide)
Par défaut: longueur exacte
$bChars [optionnel]
    True - Retourne la longueur en caractères
    False - Retourne la longueur retour en octets
Par défaut: en octets

Valeur de retour

Succès: Retourne la longueur, en octets ou en caractères.
Échec: Retourne 0 et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
102 - $bExact doit être True ou False
103 - $bChars doit être True ou False

Voir aussi

Consultez EM_GETTEXTLENGTHEX dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $hRichEdit
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "Ceci est du texte ajouté.")

    Report("Il y a " & _GUICtrlRichEdit_GetTextLength($hRichEdit, True, True) & _
            " caractères dans le contrôle")

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    Wend

    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report