UDF > GUI > GuiMonthCal >

_GUICtrlMonthCal_SetMonthDelta

Définit le pas de défilement des mois dans un calendrier mensuel

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetMonthDelta ( $hWnd, $iDelta )

Paramètres

$hWnd ID ou handle du contrôle Month Calendar
$iDelta Valeur représentant le nombre de mois qui définit la vitesse de défilement du contrôle.
Si cette valeur est égale à zéro, le delta des mois est réinitialisé à la valeur par défaut qui est le nombre de mois affichés dans le contrôle.

Valeur de retour

Retourne une valeur INT qui représente la vitesse de défilement des mois précédemment défini.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idMonthCal

    ; Crée GUI
    GUICreate("Month Calendar Set Month Delta", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)

    ; Crée un contrôle mémo
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient/Définit le delta des mois
    _GUICtrlMonthCal_SetMonthDelta($idMonthCal, 2)
    MemoWrite("Month delta: " & _GUICtrlMonthCal_GetMonthDelta($idMonthCal))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite