UDF > GUI > GuiMonthCal >

_GUICtrlMonthCal_SetCurSel

Définit la date à sélectionner

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetCurSel ( $hWnd, $iYear, $iMonth, $iDay )

Paramètres

$hWnd ID ou handle du contrôle Month Calendar
$iYear Valeur de l'année
$iMonth Valeur du mois
$iDay valeur jour

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlMonthCal_GetCurSel

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tTime, $idMonthCal

    ; Crée une GUI
    GUICreate("Month Calendar Set Cur Sel", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient/Définit la sélection en cours
    _GUICtrlMonthCal_SetCurSel($idMonthCal, @YEAR, 8, 19)
    $tTime = _GUICtrlMonthCal_GetCurSel($idMonthCal)
    MemoWrite("Current selection : " & StringFormat("%02d/%02d/%04d", DllStructGetData($tTime, "Month"), _
            DllStructGetData($tTime, "Day"), _
            DllStructGetData($tTime, "Year")))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite