UDF > GUI > GuiMonthCal >

_GUICtrlMonthCal_SetCalendarBorder

Définit la taille de la bordure, en pixels

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetCalendarBorder ( $hWnd [, $iBorderSize = 4 [, $bSetBorder = True]] )

Paramètres

$hWnd ID ou handle du contrôle Month Calendar
$iBorderSize [optionnel] Nombre de pixels de la taille de la bordure
$bSetBorder [optionnel] Une des valeurs suivantes:
    True - La taille de la bordure est définie par le nombre de pixels spécifié par $iBorderSize
    False - La taille de la bordure est réinitialisé à la valeur par défaut spécifiée par le thème, ou zéro si les thèmes ne sont pas utilisés

Valeur de retour

Aucune.

Remarque

Nécessite Windows Vista ou une version ultérieure.

En relation

_GUICtrlMonthCal_GetCalendarBorder

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idMonthCal

    ; Crée une GUI
    GUICreate("Month Calendar", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

    ; Crée un contrôle mémo
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient/Définit la bordure du calendrier
    MemoWrite("Border in pixels: " & _GUICtrlMonthCal_GetCalendarBorder($idMonthCal))
    Sleep(3000)
    GUISetState(@SW_LOCK)
    _GUICtrlMonthCal_SetCalendarBorder($idMonthCal, 2)
    MemoWrite("Bordure en pixels: " & _GUICtrlMonthCal_GetCalendarBorder($idMonthCal))
    GUISetState(@SW_UNLOCK)
    Sleep(3000)
    GUISetState(@SW_LOCK)
    _GUICtrlMonthCal_SetCalendarBorder($idMonthCal, 0, False)
    MemoWrite("Bordure en pixels: " & _GUICtrlMonthCal_GetCalendarBorder($idMonthCal))
    GUISetState(@SW_UNLOCK)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite