UDF > GUI > GuiMonthCal >

_GUICtrlMonthCal_GetMonthRangeMax

Obtient la date qui représente la limite haute de l'affichage du contrôle

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetMonthRangeMax ( $hWnd [, $bPartial = False] )

Paramètres

$hWnd ID ou handle du contrôle Month Calendar
$bPartial [optionnel] Spécifie la portée des limites de la plage à récupérer:
    True - Les mois précédents et suivants sont inclus
    False - Seuls les mois qui sont entièrement affichés sont inclus

Valeur de retour

Retourne une structure $tagSYSTEMTIME.

En relation

$tagSYSTEMTIME, _GUICtrlMonthCal_GetMonthRange, _GUICtrlMonthCal_GetMonthRangeMaxStr, _GUICtrlMonthCal_GetMonthRangeMin

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tMin, $tMax, $idMonthCal

    ; Crée une GUI
    GUICreate("Month Calendar Get Month Range Max", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient la plage des mois
    $tMin = _GUICtrlMonthCal_GetMonthRangeMin($idMonthCal)
    $tMax = _GUICtrlMonthCal_GetMonthRangeMax($idMonthCal)
    MemoWrite("Month range minimum: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tMin, "Month"), _
            DllStructGetData($tMin, "Day"), _
            DllStructGetData($tMin, "Year")))
    MemoWrite("Month range maximum: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tMax, "Month"), _
            DllStructGetData($tMax, "Day"), _
            DllStructGetData($tMax, "Year")))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite