UDF > GUI > GuiMonthCal >

_GUICtrlMonthCal_GetCurSelStr

Obtient la date actuellement sélectionnée sous forme de chaîne

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetCurSelStr ( $hWnd [, $sFormat = "%02d/%02d/%04d"] )

Paramètres

$hWnd ID ou handle du contrôle Month Calendar
$sFormat [optionnel] Chaîne StringFormat utilisée pour formater la date

Valeur de retour

Renvoie la date dans le format spécifié.

En relation

_GUICtrlMonthCal_GetCurSel

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idMonthCal

    ; Crée une GUI
    GUICreate("Month Calendar Get Cur Sel String", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient la sélection en cours
    MemoWrite("Current selection : " & _GUICtrlMonthCal_GetCurSelStr($idMonthCal))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite