UDF > GUI > GuiMonthCal >

_GUICtrlMonthCal_GetColor

Obtient la couleur d'une zone donnée d'un contrôle calendrier

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetColor ( $hWnd, $iIndex )

Paramètres

$hWnd ID ou handle du contrôle Month Calendar
$iIndex Caractèrise la couleur qu'on veut:
    $MCSC_BACKGROUND - Couleur de fond qui apparaît entre les mois
    $MCSC_TEXT - Couleur utilisée pour afficher le texte dans un mois
    $MCSC_TITLEBK - Couleur du fond utilisée dans le titre du calendrier
    $MCSC_TITLETEXT - Couleur du texte utilisée dans le titre du calendrier
    $MCSC_MONTHBK - Couleur du fond qui apparaît dans le mois
    $MCSC_TRAILINGTEXT - Couleur utilisée pour les jours de la fin du mois précédent et du début du mois suivant.

Valeur de retour

Succès: Retourne la couleur de la zone indiquée.
Échec: Retourne -1.

En relation

_GUICtrlMonthCal_SetColor

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    ; Crée une GUI
    GUICreate("Month Calendar Get Color", 400, 300)
    Local $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 4, 188, 392, 108, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient/Définit des couleurs du calendrier
    MemoWrite("Background: 0x" & Hex(_GUICtrlMonthCal_GetColor($idMonthCal, $MCSC_MONTHBK), 6))
    ; _GUICtrlMonthCal_SetColor($idMonthCal, $MCSC_MONTHBK, $CLR_MONEYGREEN)
    _GUICtrlMonthCal_SetColor($idMonthCal, $MCSC_TEXT, 0xB02B00)
    _GUICtrlMonthCal_SetColor($idMonthCal, $MCSC_TITLEBK, 0x5EFFFE)
    _GUICtrlMonthCal_SetColor($idMonthCal, $MCSC_TITLETEXT, 0x0000FF)
    _GUICtrlMonthCal_SetColor($idMonthCal, $MCSC_MONTHBK, 0x87C4FF)
    _GUICtrlMonthCal_SetColor($idMonthCal, $MCSC_TRAILINGTEXT, 0x997777)
    MemoWrite("Background: 0x" & Hex(_GUICtrlMonthCal_GetColor($idMonthCal, $MCSC_MONTHBK), 6))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite