UDF > GUI > GuiMenu >

_GUICtrlMenu_GetMenuBarInfo

Obtient des informations sur la barre de menu spécifié

#include <GuiMenu.au3>
_GUICtrlMenu_GetMenuBarInfo ( $hWnd [, $iItem = 0 [, $iObject = 1]] )

Paramètres

$hWnd Handle de la fenêtre dont les informations doivent être extraites
$iItem [optionnel] Spécifie l'élément pour lequel vous souhaitez obtenir des informations. Si 0, la fonction Obtient des informations sur le menu lui-même.
Si 1, la fonction obtient des informations sur le premier élément du menu, et ainsi de suite.
$iObject [optionnel] Spécifie l'objet du menu:
    0 - Le menu déroulant associé à la fenêtre
    1 - La barre de menu associé à la fenêtre
    2 - Le menu système associé à la fenêtre

Valeur de retour

Succès: Retourne un tableau avec le format suivant:
    [0] - Coordonnée X du coin supérieur gauche du rectangle
    [1] - Coordonnée Y du coin supérieur gauche du rectangle,
    [2] - Coordonnée X du coin inférieur droit du rectangle
    [3] - Coordonnée Y du coin inférieur droit du rectangle
    [4] - Handle de la barre de menu ou du menu déroulant
    [5] - Handle du sous-menu
    [6] - True si la barre de menu a le focus, sinon False
    [7] - True si l'élément de menu a le focus, sinon False
Échec: Définit @error <> 0.

Voir aussi

Consultez GetMenuBarInfo dans la librairie MSDN.

Exemple

#include <GuiMenu.au3>

Example()

Func Example()
    Local $hWnd, $aInfo

    ; Ouvre le Bloc-Notes
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")

    ; Obtient des infos sur la barre de menu
    $aInfo = _GUICtrlMenu_GetMenuBarInfo($hWnd)
    Writeln("Left ............: " & $aInfo[0])
    Writeln("Top .............: " & $aInfo[1])
    Writeln("Right ...........: " & $aInfo[2])
    Writeln("Bottom ..........: " & $aInfo[3])
    Writeln("Menu handle .....: 0x" & Hex($aInfo[4]))
    Writeln("Submenu Handle ..: 0x" & Hex($aInfo[5]))
    Writeln("Menu bar focused : " & $aInfo[6])
    Writeln("Menu élément focused: " & $aInfo[7])
EndFunc   ;==>Example

; Écrire une ligne de texte dans le Bloc-Notes
Func Writeln($sText)
    ControlSend("[CLASS:Notepad]", "", "Edit1", $sText & @CRLF)
EndFunc   ;==>Writeln