UDF > GUI > GuiMenu >

_GUICtrlMenu_CheckMenuItem

Coche/décoche l'élément du menu spécifiée pour le sélectionner ou le désélectionner

#include <GuiMenu.au3>
_GUICtrlMenu_CheckMenuItem ( $hMenu, $iItem [, $bCheck = True [, $bByPos = True]] )

Paramètres

$hMenu Handle du contrôle Menu
$iItem Identifiant ou position de l'élément du menu à cocher/décocher
$bCheck [optionnel] True pour cocher la case, False pour la décocher
$bByPos [optionnel] Indicateur de l'identifiant du Menu:
    True  - $iItem est la position de base 0 de l'élément
    False - $iItem est l'identifiant de l'élément du menu

Valeur de retour

Succès: Retourne l'état précédent de l'élément du menu ($MF_CHECKED ou $MF_UNCHECKED).
Échec: Retourne -1.

Remarque

Un élément dans une barre de menu ne peut pas avoir de case à cocher. Le paramètre $iItem identifie un élément qui ouvre un sous-menu ou un élément de commande.
Pour un élément qui ouvre un sous-menu, le paramètre $iItem doit spécifier la position de l'élément.
Pour un élément de commande, le paramètre $iItem doit spécifier la position ou l'identifiant de l'élément.

En relation

_GUICtrlMenu_CheckRadioItem

Voir aussi

Consultez CheckMenuItem dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Example()

Func Example()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Crée une GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Crée un menu File
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $e_idExit)

    ; Crée un menu Edit
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $e_idPaste)

    ; Crée un menu Help
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hHelp, 0, "&About", $e_idAbout)

    ; Crée un menu Main
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, $hHelp)

    ; Attache le menu à la fenêtre
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState(@SW_SHOW)

    ; Coche l'élément de menu About
    _GUICtrlMenu_CheckMenuItem($hHelp, 0)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example