UDF > GUI > GuiListView >

_GUICtrlListView_FindInText

Recherche un élément qui contient le texte spécifié n'importe où dans son texte

#include <GuiListView.au3>
_GUICtrlListView_FindInText ( $hWnd, $sText [, $iStart = -1 [, $bWrapOK = True [, $bReverse = False]]] )

Paramètres

$hWnd ID/handle du contrôle
$sText Texte à chercher
$iStart [optionnel] Index de l'élément, de base 0, à partir duquel la recherche commence ou -1 pour commencer au début.
L'élément spécifié est lui-même exclu de la recherche.
$bWrapOK [optionnel] Si True, la recherche se poursuivra avec le premier élément si aucune correspondance n'est trouvée jusque là
$bReverse [optionnel] Si True, la recherche commence à $iStart - 1 et décroit jusqu'à zéro. Si $bWrapOK = True la recherche continue à la fin

Valeur de retour

Succès: Retourne l'index de l'élément, de base 0.
Échec: Retourne -1.

Remarque

La recherche est insensible à la casse. Contrairement à _GUICtrlListView_FindText() , cette fonction va rechercher tous les sous-éléments du texte.

En relation

_GUICtrlListView_FindText

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $iI, $idListview

    GUICreate("ListView Find In Text", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_InsertColumn($idListview, 0, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_BeginUpdate($idListview)
    For $iI = 1 To 49
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_AddItem($idListview, "Target item")
    For $iI = 51 To 100
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($idListview)

    ; Cherche 'target'
    $iI = _GUICtrlListView_FindInText($idListview, "tArGeT")
    MsgBox($MB_SYSTEMMODAL, "Information", "Target Item Index: " & $iI)
    _GUICtrlListView_EnsureVisible($idListview, $iI)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example