UDF > GUI > GuiListView >

_GUICtrlListView_Arrange

Arrange les éléments dans un mode d'affichage avec icônes

#include <GuiListView.au3>
_GUICtrlListView_Arrange ( $hWnd [, $iArrange = 0] )

Paramètres

$hWnd ID/handle du contrôle
$iArrange [optionnel] Alignement. Peut prendre l'une des valeurs suivantes:
    0 - Aligne les éléments en accord avec la valeur par défaut du contrôle
    1 - Aligne les éléments le long du bord gauche de la fenêtre
    2 - Aligne les éléments le long du bord supérieur de la fenêtre
    3 - Attire les icônes à la position de grille la plus proche.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlListView_SetItemPosition

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Arrange", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_InsertColumn($idListview, 0, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_BeginUpdate($idListview)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($idListview)

    ; Déplace l'élément 2
    _GUICtrlListView_SetView($idListview, 3)
    _GUICtrlListView_SetItemPosition($idListview, 1, 100, 100)

    MsgBox($MB_SYSTEMMODAL, "Information", "Arranging items")
    _GUICtrlListView_Arrange($idListview)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example