UDF > GUI > GuiListBox >

_GUICtrlListBox_SelItemRange

Sélectionne un ou plusieurs éléments consécutifs dans une ListBox à sélection multiple

#include <GuiListBox.au3>
_GUICtrlListBox_SelItemRange ( $hWnd, $iFirst, $iLast [, $bSelect = True] )

Paramètres

$hWnd ID/handle du contrôle
$iFirst Index du premier élément à sélectionner, compté à partir de 0
$iLast Index du dernier élément à sélectionner, compté à partir de 0
$bSelect [optionnel] Indique si la fonction sélectionne ou désélectionne.
Si ce paramètre est True, les chaînes sont sélectionnées et mises en surbrillance.
S'il est False, la surbrillance est enlevée et les chaînes ne sont plus sélectionnées.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Utilisez cette fonction qu'avec des ListBox à sélection multiple.
Cette fonction peut sélectionner une plage que dans les 65 536 premiers éléments.

En relation

_GUICtrlListBox_SelItemRangeEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>

Example()

Func Example()
    Local $sText, $idListBox

    ; Crée une GUI
    GUICreate("List Box Sel Item Range", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
    GUISetState(@SW_SHOW)

    ; Ajoute des chaînes
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 10
        $sText = StringFormat("%03d : Random string ", Random(1, 100, 1))
        For $iX = 1 To Random(1, 20, 1)
            $sText &= Chr(Random(65, 90, 1))
        Next
        _GUICtrlListBox_AddString($idListBox, $sText)
    Next
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Sélectionne quelques éléments
    _GUICtrlListBox_SelItemRange($idListBox, 3, 5)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example