UDF > GUI > GuiIPAddress >

_GUICtrlIpAddress_SetArray

Définit l'adresse dans un contrôle IPAddress (à partir d'un tableau)

#include <GuiIPAddress.au3>
_GUICtrlIpAddress_SetArray ( $hWnd, $aAddress )

Paramètres

$hWnd Handle du contrôle
$aAddress Tableau formaté comme suit:
[0] - 1ère champ d'adresse
[1] - 2ème champ d'adresse
[2] - 3ème champ d'adresse
[3] - 4ème champ d'adresse

Valeur de retour

Aucune.

En relation

_GUICtrlIpAddress_GetArray

Exemple

#include <GUIConstantsEx.au3>
#include <GuiIPAddress.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGui, $aIP[4] = [24, 168, 2, 128], $hIPAddress

    $hGui = GUICreate("IP Address Control Set (Array) Example", 400, 300)
    $hIPAddress = _GUICtrlIpAddress_Create($hGui, 2, 4, 125, 20)
    $g_idMemo = GUICtrlCreateEdit("", 2, 28, 396, 270, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    _GUICtrlIpAddress_SetArray($hIPAddress, $aIP)

    $aIP = _GUICtrlIpAddress_GetArray($hIPAddress)

    MemoWrite("Field 1 .....: " & $aIP[0])
    MemoWrite("Field 2 .....: " & $aIP[1])
    MemoWrite("Field 3 .....: " & $aIP[2])
    MemoWrite("Field 4 .....: " & $aIP[3])

    ; Attend que l'utilisateur ferme la GUI
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite