UDF > GUI > GuiHeader >

_GUICtrlHeader_SetItemText

Définit le texte d'un élément

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemText ( $hWnd, $iIndex, $sText )

Paramètres

$hWnd Handle du contrôle
$iIndex Index de l'élément, compté à partir de 0
$sText Nouveau texte de l'élément. Voir Remarque.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Si un rappel de notification est nécessaire, vous devez spécifier $sText = -1 (LPSTR_TEXTCALLBACK).

En relation

_GUICtrlHeader_GetItemText

Exemple

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hHeader

    ; Crée une GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
    $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; Définit le texte de la colonne 1
    _GUICtrlHeader_SetItemText($hHeader, 0, "Column X")

    ; Montre le texte de la colonne 1
    MemoWrite("Column 1 text: " & _GUICtrlHeader_GetItemText($hHeader, 0))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite