UDF > GUI > GuiHeader >

_GUICtrlHeader_SetItemFlags

Définit les indicateurs d'un élément

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemFlags ( $hWnd, $iIndex, $iFlags )

Paramètres

$hWnd Handle du contrôle
$iIndex Index de l'élément, compté à partir de 0
$iFlags Paramètres de l'élément. Peut être une combinaison des valeurs suivantes:
    1 - Affiche une image à partir d'une liste d'images
    2 - Le texte se lit dans le sens opposé par rapport au texte de la fenêtre parent
    4 - Dessine une flèche vers le bas sur cet élément
    8 - Dessine une flèche vers le haut sur cet élément

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlHeader_GetItemFlags

Exemple

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hHeader

    ; Crée une GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
    $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; Définit le flag de la colonne 1
    _GUICtrlHeader_SetItemFlags($hHeader, 0, 4)

    ; Montre le flag de la colonne 1
    MemoWrite("Column 1 flags: " & _GUICtrlHeader_GetItemFlags($hHeader, 0))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite