UDF > GUI > GuiHeader >

_GUICtrlHeader_SetItemAlign

Définit l'alignement du texte d'un élément

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemAlign ( $hWnd, $iIndex, $iAlign )

Paramètres

$hWnd Handle du contrôle
$iIndex Index de l'élément, compté à partir de 0
$iAlign Alignement du texte:
    0 - Le texte est aligné à gauche
    1 - Le texte est aligné à droite
    2 - Le texte est centré

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlHeader_GetItemAlign

Exemple

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hHeader

    ; Crée une GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
    $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; Définit l'alignement de la colonne 1
    _GUICtrlHeader_SetItemAlign($hHeader, 0, 2)

    ; Affiche l'alignement de la colonne 1
    MemoWrite("Column 1 alignment: " & _GUICtrlHeader_GetItemAlign($hHeader, 0))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite