UDF > GUI > GuiHeader >

_GUICtrlHeader_GetItemRect

Obtient, dans un tableau, le rectangle englobant d'un élément donné

#include <GuiHeader.au3>
_GUICtrlHeader_GetItemRect ( $hWnd, $iIndex )

Paramètres

$hWnd Handle du contrôle
$iIndex Index de l'élément, compté à partir de 0

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - coordonnée X du coin supérieur gauche du rectangle
    [1] - coordonnée Y du coin supérieur gauche du rectangle,
    [2] - coordonnée X du coin inférieur droit du rectangle
    [3] - Coordonnée Y du coin inférieur droit du rectangle

En relation

_GUICtrlHeader_GetItemRectEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hHeader, $aRect

    ; Crée une GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
    $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; Affiche le rectangle de la colonne 1
    $aRect = _GUICtrlHeader_GetItemRect($hHeader, 0)
    MemoWrite("Column 1 left .: " & $aRect[0])
    MemoWrite("Column 1 top ..: " & $aRect[1])
    MemoWrite("Column 1 right : " & $aRect[2])
    MemoWrite("Column 1 bottom: " & $aRect[3])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite