UDF > GUI > GuiHeader >

_GUICtrlHeader_GetBitmapMargin

Obtient la largeur de la marge du bitmap

#include <GuiHeader.au3>
_GUICtrlHeader_GetBitmapMargin ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne la largeur de la marge de bitmap en pixels. Si la marge du bitmap n'a pas été précisé précédemment, la valeur par défaut égale à 3 * GetSystemMetrics(SM_CXEDGE) est retournée.
Échec: Retourne 0.

En relation

_GUICtrlHeader_SetBitmapMargin

Exemple

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hHeader

    ; Crée une GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
    $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; Affiche la marge courante du bitmap
    MemoWrite("Current margin .: " & _GUICtrlHeader_GetBitmapMargin($hHeader))

    ; Définit une nouvelle marge
    _GUICtrlHeader_SetBitmapMargin($hHeader, 8)

    ; Affiche la noouvelle marge
    MemoWrite("New margin .....: " & _GUICtrlHeader_GetBitmapMargin($hHeader))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite