UDF > GUI > GuiEdit >

_GUICtrlEdit_SetCueBanner

Définit le texte de la bannière affichée dans un contrôle d'édition

#include <GuiEdit.au3>
_GUICtrlEdit_SetCueBanner ( $hWnd, $sText [, $bOnFocus = False] )

Paramètres

$hWnd ID/Handle du contrôle
$sText Chaîne qui contient le texte
$bOnFocus [optionnel] True - la bannière sera visible même quand le contrôle d'édition aura le focus.
False (par défaut) - la bannière disparaitra quand l'utilisateur cliquera dans le contrôle.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarques

La bannière est le texte qui s'affiche dans un contrôle d'édition quand il n'a pas le focus.

Windows Vista ou une version ultérieure.

En relation

_GUICtrlEdit_GetCueBanner

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate('Example', 300, 150)
    GUISetFont(9, 400, 0, 'Segoe UI')

    Local $idUsername = GUICtrlCreateInput('', 10, 10, 125, 25)
    _GUICtrlEdit_SetCueBanner($idUsername, "Search folder")

    Local $idPassword = GUICtrlCreateInput('', 10, 40, 125, 25)
    _GUICtrlEdit_SetCueBanner($idPassword, "Search...")

    Local $idClose = GUICtrlCreateButton("Close", 210, 120, 85, 25)
    ControlFocus($hGUI, "", $idClose)

    GUISetState(@SW_SHOW, $hGUI)

    MsgBox($MB_SYSTEMMODAL, "", _GUICtrlEdit_GetCueBanner($idPassword))

    Local $iMsg
    Do
        $iMsg = GUIGetMsg()  
    Until $iMsg = $GUI_EVENT_CLOSE Or $iMsg = $idClose

    GUIDelete($hGUI)
EndFunc   ;==>Example