UDF > GUI > GuiDateTimePicker >

_GUICtrlDTP_SetSystemTime

Définit, à partir d'un tableau, la date et l'heure à sélectionner

#include <GuiDateTimePicker.au3>
_GUICtrlDTP_SetSystemTime ( $hWnd, ByRef $aDate )

Paramètres

$hWnd Handle du contrôle
$aDate Tableau formaté comme il suit:
    [0] - Si True, le contrôle sera défini à "no date"
    [1] - Année
    [2] - Mois
    [3] - Jour
    [4] - Heure
    [5] - Minute
    [6] - Seconde

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlDTP_GetSystemTime

Exemple

#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>

Global $g_idMemo, $g_aDate

Example()

Func Example()
    Local $hDTP, $a_Date[7] = [False, @YEAR, 8, 19, 21, 57, 34]

    ; Crée une GUI
    GUICreate("DateTimePick Set System Time", 400, 300)
    $hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit le format de l'affichage
    _GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")

    ; Définit l'heure du système
    _GUICtrlDTP_SetSystemTime($hDTP, $a_Date)

    ; Affiche l'heure du système
    $g_aDate = _GUICtrlDTP_GetSystemTime($hDTP)
    MemoWrite("Selected date: " & GetDateStr())
    MemoWrite("Selected time: " & GetTimeStr())

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Retourne la partie date
Func GetDateStr()
    Return StringFormat("%02d/%02d/%04d", $g_aDate[1], $g_aDate[2], $g_aDate[0])
EndFunc   ;==>GetDateStr

; Retourne la partie heure
Func GetTimeStr()
    Return StringFormat("%02d:%02d:%02d", $g_aDate[3], $g_aDate[4], $g_aDate[5])
EndFunc   ;==>GetTimeStr

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite