UDF > GUI > GuiDateTimePicker >

_GUICtrlDTP_SetRange

Définit, à partir d'un tableau, les limites minimale et maximale de la date et de l'heure admissibles

#include <GuiDateTimePicker.au3>
_GUICtrlDTP_SetRange ( $hWnd, ByRef $aRange )

Paramètres

$hWnd Handle du contrôle
$aRange Tableau formaté comme il suit:
    [ 0] - True si les données Min doivent être définies, sinon False
    [ 1] - Min de l'année
    [ 2] - Min du mois
    [ 3] - Min du jour
    [ 4] - Min de l'heure
    [ 5] - Min des minutes
    [ 6] - Min des secondes
    [ 7] - True si les données Max doivent être définies, sinon False
    [ 8] - Max de l'année
    [ 9] - Max du mois
    [10] - Max du jour
    [11] - Max de l'heure
    [12] - Max des minute
    [13] - Max des secondes

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlDTP_GetRange

Exemple

#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>

Global $g_idMemo, $g_aRange[14] = [True, @YEAR, 1, 1, 21, 45, 32, True, @YEAR, 12, 31, 23, 59, 59]

Example()

Func Example()
    Local $hDTP

    ; Crée une GUI
    GUICreate("DateTimePick Set Range", 400, 300)
    $hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit le format d'affichage
    _GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")

    ; Définit la plage des  dates
    _GUICtrlDTP_SetRange($hDTP, $g_aRange)

    ; Affiche la plage des dates
    $g_aRange = _GUICtrlDTP_GetRange($hDTP)
    MemoWrite("Minimum date: " & GetDateStr(0))
    MemoWrite("Maximum date: " & GetDateStr(7))
    MemoWrite("Minimum time: " & GetTimeStr(4))
    MemoWrite("Maximum time: " & GetTimeStr(11))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Retourne la partie date
Func GetDateStr($iOff = 0)
    Return StringFormat("%02d/%02d/%04d", $g_aRange[$iOff + 2], $g_aRange[$iOff + 3], $g_aRange[$iOff + 1])
EndFunc   ;==>GetDateStr

; Retourne la partie heure
Func GetTimeStr($iOff = 0)
    Return StringFormat("%02d:%02d:%02d", $g_aRange[$iOff], $g_aRange[$iOff + 1], $g_aRange[$iOff + 2])
EndFunc   ;==>GetTimeStr

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite