UDF > GUI > GuiDateTimePicker >

_GUICtrlDTP_GetSystemTimeEx

Obtient, dans une structure, la date et l'heure sélectionnées

#include <GuiDateTimePicker.au3>
_GUICtrlDTP_GetSystemTimeEx ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne une structure $tagSYSTEMTIME.
Échec: Définit @error <> 0.
@error: $GDT_NONE - le contrôle a été créé avec le style de $DTS_SHOWNONE et la case à cocher du contrôle n'a pas été sélectionné
$GDT_ERROR - une erreur s'est produite.

En relation

$tagSYSTEMTIME, _GUICtrlDTP_GetSystemTime, _GUICtrlDTP_SetSystemTimeEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>

Global $g_idMemo, $g_tDate

Example()

Func Example()
    Local $hDTP

    ; Crée une GUI
    GUICreate("DateTimePick Get System TimeEx", 400, 300)
    $hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit le format d'affichage
    _GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")

    ; Définit l'heure  système
    $g_tDate = DllStructCreate($tagSYSTEMTIME)
    DllStructSetData($g_tDate, "Year", @YEAR)
    DllStructSetData($g_tDate, "Month", 8)
    DllStructSetData($g_tDate, "Day", 19)
    DllStructSetData($g_tDate, "Hour", 21)
    DllStructSetData($g_tDate, "Minute", 57)
    DllStructSetData($g_tDate, "Second", 34)
    _GUICtrlDTP_SetSystemTimeEx($hDTP, $g_tDate)

    ; Affiche l'heure  système
    $g_tDate = _GUICtrlDTP_GetSystemTimeEx($hDTP)
    MemoWrite("Selected date: " & GetDateStr())
    MemoWrite("Selected time: " & GetTimeStr())

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Retourne la partie date
Func GetDateStr()
    Return StringFormat("%02d/%02d/%04d", DllStructGetData($g_tDate, "Month"), DllStructGetData($g_tDate, "Day"), DllStructGetData($g_tDate, "Year"))
EndFunc   ;==>GetDateStr

; Retourne la partie heure
Func GetTimeStr()
    Return StringFormat("%02d:%02d:%02d", DllStructGetData($g_tDate, "Hour"), DllStructGetData($g_tDate, "Minute"), DllStructGetData($g_tDate, "Second"))
EndFunc   ;==>GetTimeStr

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite