UDF > GUI > GuiDateTimePicker >

_GUICtrlDTP_GetMCColor

Récupère la couleur d'une zone spécifiée

#include <GuiDateTimePicker.au3>
_GUICtrlDTP_GetMCColor ( $hWnd, $iIndex )

Paramètres

$hWnd Handle du contrôle
$iIndex Indique la zone du calendrier mensuel dont la couleur est à récupérer:
    0 - Couleur de fond affichée entre les mois
    1 - Couleur utilisée pour le texte de la zone mois
    2 - Couleur de fond utilisée pour le titre du calendrier
    3 - Couleur utilisée pour le texte dans le titre du calendrier
    4 - Couleur de fond affichée dans le mois
    5 - Couleur utilisée pour afficher le texte du jour de début et de fin

Valeur de retour

Succès: Retourne la couleur définie pour la partie spécifiée du contrôle.
Échec: Retourne -1.

En relation

_GUICtrlDTP_SetMCColor

Exemple

#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>
#include <MsgBoxConstants.au3>

Global $g_idMemo

Example() ; Utilise le contrôle interne autoit

Func Example()
    Local $hDTP

    ; Crée une GUI
    GUICreate("DateTimePick Get Month Calendar Color", 400, 300)
    $hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit le format d'affichage
    _GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")

    ; Définit la couleur du fond du mois du calendrier
    _GUICtrlDTP_SetMCColor($hDTP, 2, $CLR_MONEYGREEN)

    ; Obtient les couleurs du DTP
    MemoWrite("Background between months: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 0), 6))
    MemoWrite("Text within months ......: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 1), 6))
    MemoWrite("Title background ........: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 2), 6))
    MemoWrite("Title text ..............: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 3), 6))
    MemoWrite("Background within months : " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 4), 6))
    MemoWrite("Header trailing .........: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 5), 6))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite