UDF > GUI > GuiComboBox >


_GUICtrlComboBox_SetDroppedWidth

Définit la largeur maximale admissible, en pixels, de la liste déroulante d'une ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetDroppedWidth ( $hWnd, $iWidth )

Paramètres

$hWnd ID/handle du contrôle
$iWidth La largeur de la zone de liste déroulante, en pixels,

Valeur de retour

Succès: Retourne la nouvelle largeur de la zone de liste.
Échec: Retourne -1.

Remarques

Par défaut, la largeur minimale admissible de la liste déroulante est nulle.
La largeur de la zone de liste est soit la largeur minimale admissible ou la largeur de la ComboBox, si elle est plus grande.

Utilisez le style $CBS_DROPDOWN ou $CBS_DROPDOWNLIST.

En relation

_GUICtrlComboBox_GetDroppedWidth, _GUICtrlComboBoxEx_GetDroppedState

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Set Dropped Width", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Définit Dropped Width
    _GUICtrlComboBox_SetDroppedWidth($idCombo, 500)

    ; Obtient Dropped Width
    MsgBox($MB_SYSTEMMODAL, "Information", "Dropped Width: " & _GUICtrlComboBox_GetDroppedWidth($idCombo))

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example