UDF > GUI > GuiComboBox >

_GUICtrlComboBox_InsertString

Insère une chaîne

#include <GuiComboBox.au3>
_GUICtrlComboBox_InsertString ( $hWnd, $sText [, $iIndex = -1] )

Paramètres

$hWnd ID/handle du contrôle
$sText Chaîne de texte à insérer
$iIndex [optionnel] Spécifie l'index, à partir de 0, de la position à laquelle insérer la chaîne.

Valeur de retour

Succès: Retourne un index, à partir de 0, de la position à laquelle la chaîne a été insérée.
Échec: Retourne -1.

Remarques

Si le paramètre $iIndex est égal à -1, la chaîne est ajoutée à la fin de la liste.

Si la ComboBox a le style $WS_HSCROLL et que vous insérez une chaîne plus large que la ComboBox, vous devez utiliser la fonction _GUICtrlComboBox_SetHorizontalExtent() pour être sûr que la barre de défilement horizontale apparaîsse.

En relation

_GUICtrlComboBox_AddString, _GUICtrlComboBox_InitStorage, _GUICtrlComboBox_SetHorizontalExtent

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Insert String", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Insère une chaîne
    _GUICtrlComboBox_InsertString($idCombo, "Some Inserted string", 0)

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example