UDF > GUI > GuiComboBox >

_GUICtrlComboBox_FindStringExact

Recherche la forme exacte d'une chaîne

#include <GuiComboBox.au3>
_GUICtrlComboBox_FindStringExact ( $hWnd, $sText [, $iIndex = -1] )

Paramètres

$hWnd ID/handle du contrôle
$sText Chaîne à rechercher
$iIndex [optionnel]Index, à partir de 0, de l'élément qui précède le premier élément à rechercher

Valeur de retour

Succès: Retourne l'index, à partir de 0, de l'élément correspondant.
Échec: Retourne -1.

Remarques

Trouve la première chaîne qui correspond exactement à la chaîne spécifiée dans le paramètre $sText.

Lorsque la recherche atteint la fin de la liste, la fonction continue à partir du haut de la liste pour retourner à l'élément spécifié par $iIndex.

Si $iIndex est -1, la liste entière est scannée depuis le début.

En relation

_GUICtrlComboBox_SelectString

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Find String Exact", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, "", $DDL_DRIVES, False)
    _GUICtrlComboBox_AddString($idCombo, "This is a test")
    _GUICtrlComboBox_AddDir($idCombo, "", $DDL_DRIVES)
    _GUICtrlComboBox_AddString($idCombo, "This is eXact")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Cherche la chaîne
    MsgBox($MB_SYSTEMMODAL, "Information", "Find String: " & _GUICtrlComboBox_FindStringExact($idCombo, "This is eXact"))

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example