UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_SetTopIndex

Rend visible un élément particulier dans la zone de liste d'une ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetTopIndex ( $hWnd, $iIndex )

Paramètres

$hWnd Handle pour le contrôle
$iIndex Index, compté à partir de 0, de l'élément de la liste

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Le système fait défiler le contenu de la ListBox afin que soit l'élément spécifié apparaîsse en haut de la zone de liste ou au maximum de l'intervalle de défilement lorsqu'il est atteint.

En relation

_GUICtrlComboBoxEx_GetTopIndex

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hCombo

    ; Crée une GUI
    $hGUI = GUICreate("ComboBoxEx Set Top Index", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100, $CBS_SIMPLE)
    GUISetState(@SW_SHOW)

    _GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)
    _GUICtrlComboBoxEx_BeginUpdate($hCombo)

    For $x = 0 To 149
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    ; Définit Top Index
    MsgBox($MB_SYSTEMMODAL, "Information", "Set Top Index: " & _GUICtrlComboBoxEx_SetTopIndex($hCombo, Random(50, 149, 1)))
    MsgBox($MB_SYSTEMMODAL, "Information", "Top Index: " & _GUICtrlComboBoxEx_GetTopIndex($hCombo))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example