UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_GetList

Récupère, dans une chaîne, tous les éléments de la liste d'un contrôle ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetList ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Retourne une chaîne délimitée contenant tous les éléments de la ComboBox.

Remarque

Par défaut le séparateur est "|", il peut être changé en utilisant l'Opt("GUIDataSeparatorChar ","nouveau séparateur").

En relation

_GUICtrlComboBoxEx_GetListArray

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $aItem, $sDelimiter = "; ", $hCombo

    Opt("GUIDataSeparatorChar", $sDelimiter)

    ; Crée une GUI
    $hGUI = GUICreate("ComboBoxEx Get List", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBoxEx_AddDir($hCombo, "", $DDL_DRIVES, False)

    ; Obtient List
    $aItem = StringSplit(_GUICtrlComboBoxEx_GetList($hCombo), $sDelimiter)

    For $x = 1 To $aItem[0]
        MemoWrite($aItem[$x])
    Next

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite