UDF > GDIPlus > Pen >

_GDIPlus_PenSetStartCap

Définit l'embout de début de ligne pour un crayon

#include <GDIPlus.au3>
_GDIPlus_PenSetStartCap ( $hPen, $iLineCap )

Paramètres

$hPen Handle de l'objet Pen
$iLineCap Style d'embout de ligne:
    0x00 - La ligne se termine au dernier point. La fin est d'équerre
    0x01 - Embout carré. Le centre du carré est le dernier point de la ligne.
        Le coté du carré est la largeur de la ligne.
    0x02 - Embout circulaire. Le centre du cercle est le dernier point de la ligne.
        Le diamètre du cercle est la largeur de la ligne.
    0x03 - Embout triangulaire.
        La base du triangle est le dernier point de la ligne.
        La base du triangle est la largeur de la ligne.
    0x10 - Les extrémités de ligne ne sont pas ancrés.
    0x11 - Les extrémités de ligne sont ancrés avec un carré.
        Le centre du carré est le dernier point de la ligne.
        Le coté du carré est la largeur de la ligne.
    0x12 - Les extrémités de ligne sont ancrés par un cercle.
        Le centre du cercle est le dernier point de la ligne.
        Le cercle est plus large que la ligne.
    0x13 - Les extrémités de ligne sont ancrés avec un losange ( un carré tourné à 45 degrés ).
        Le centre du losange est le dernier point de la ligne.
        Le losange est plus large que la ligne.
    0x14 - Les extrémités de ligne sont ancrés avec des pointes de flèches.
        La pointe de la flèche se trouve au dernier point de la ligne.
        La flèche est plus large que la ligne.
    0xff - Les extrémités de ligne sont faites à partir d'un objet CustomLineCap

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Voir aussi

Cherchez GdipSetPenStartCap dans la Library MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hPen

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 400, 400)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet graphique à partir du handle de fenêtre
    _GDIPlus_GraphicsSetSmoothingMode($hGraphic, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Définit l'objet graphique à la qualité de rendu antialiasing
    _GDIPlus_GraphicsClear($hGraphic, 0xFFFFFFFF)

    $hPen = _GDIPlus_PenCreate(0xFFAA00FF, 40)
    _GDIPlus_PenSetStartCap($hPen, $GDIP_LINECAPROUND)
    _GDIPlus_PenSetEndCap($hPen, $GDIP_LINECAPROUND)

    _GDIPlus_GraphicsDrawArc($hGraphic, 60, 60, 280, 280, 135, 270, $hPen)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example