UDF > GDIPlus > Graphics >

_GDIPlus_GraphicsDrawArc

Dessine un arc d'ellipse ou de cercle

#include <GDIPlus.au3>
_GDIPlus_GraphicsDrawArc ( $hGraphics, $nX, $nY, $nWidth, $nHeight, $fStartAngle, $fSweepAngle [, $hPen = 0] )

Paramètres

$hGraphics Handle de l'objet Graphics
$nX La coordonnée X du coin supérieur gauche du rectangle qui délimite l'ellipse qui contient l'arc à dessiner
$nY La coordonnée Y du coin supérieur gauche du rectangle qui délimite l'ellipse qui contient l'arc à dessiner
$nWidth La largeur du rectangle qui délimite l'ellipse qui contient l'arc à dessiner
$nHeight La hauteur du rectangle qui délimite l'ellipse qui contient l'arc à dessiner
$fStartAngle L'angle entre l'axe des X et le point de départ de l'arc
$fSweepAngle L'angle entre les points de début et de fin de l'arc
$hPen [optionnel] Handle d'un objet Pen qui sera utilisé pour dessiner l'arc. Si 0, un crayon noir qui trace des lignes continues de largeur de 1 sera utilisé.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Voir aussi

Consultez GdipDrawArc dans la Librairie MSDN.

Exemples

Exemple 1

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Dessine des arcs
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsDrawArc($hGraphic, 160, 100, 10, 10, 180, 360)
    _GDIPlus_GraphicsDrawArc($hGraphic, 180, 100, 10, 10, 180, 360)
    _GDIPlus_GraphicsDrawArc($hGraphic, 160, 104, 30, 30, 160, -140)
    _GDIPlus_GraphicsDrawArc($hGraphic, 140, 80, 70, 70, 180, 360)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example

Exemple 2

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    _GDIPlus_Startup() ; Initialise GDI+
    Local Const $iWidth = 600, $iHeight = 600, $iBgColor = 0x303030 ; $iBGColor est au format RRGGBB

    Local $hGUI = GUICreate("GDI+ example", $iWidth, $iHeight) ; Crée une fenêtre de test
    GUISetBkColor($iBgColor, $hGUI) ; Définit la couleur de fond de la GUI
    GUISetState(@SW_SHOW)

    ; Crée un buffer graphique pour fluidifier les déplacements de l'objet gfx
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet Graphics à partir du handle de la fenêtre
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Définit pour l'objet graphique la qualité de rendu antialiasing
    Local $hPen = _GDIPlus_PenCreate(0xFFFF8080, 32) ; Format de couleur AARRGGBB (hex)
    _GDIPlus_GraphicsDrawArc($hGraphics, 100.5, 100.5, 400.25, 400.25, -45.5, 270.5, $hPen)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources GDI+
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example