UDF > GDIPlus > Pen >

_GDIPlus_PenSetDashCap

Définit le style des extrémités des tirets fait par un crayon

#include <GDIPlus.au3>
_GDIPlus_PenSetDashCap ( $hPen [, $iDash = 0] )

Paramètres

$hPen Handle de l'objet Pen
$iDash [optionnel] Style d'embout des tirets. L'un des suivants:
    $GDIP_DASHCAPFLAT - Un embout carré termine les deux extrémités de chaque tiret
    $GDIP_DASHCAPROUND - Un embout rond termine les deux extrémités de chaque tiret
    $GDIP_DASHCAPTRIANGLE - Un embout triangulaire termine les deux extrémités de chaque tiret

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_PenGetDashCap

Voir aussi

Cherchez GdipSetPenDashCap197819 dans la Library MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hPen

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Crée des ressources
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 8)
    _GDIPlus_PenSetDashStyle($hPen, $GDIP_DASHSTYLEDASHDOT)
    _GDIPlus_PenSetDashCap($hPen, $GDIP_DASHCAPTRIANGLE)

    ; Affiche l'embout des tirets de crayon
    MsgBox($MB_SYSTEMMODAL, "Information", "Pen dash cap: " & _GDIPlus_PenGetDashCap($hPen))

    ; Dessine une ligne
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example