UDF > GDIPlus > Pen >

_GDIPlus_PenSetDashStyle

Définit le style de trait du crayon

#include <GDIPlus.au3>
_GDIPlus_PenSetDashStyle ( $hPen [, $iStyle = 0] )

Paramètres

$hPen Handle de l'objet Pen
$iStyle [optionnel] Style de trait. L'un des suivants:
    $GDIP_DASHSTYLESOLID - Une ligne continue
    $GDIP_DASHSTYLEDASH - Une ligne de tirets
    $GDIP_DASHSTYLEDOT - Une ligne en pointillés
    $GDIP_DASHSTYLEDASHDOT - Une ligne qui alterne trait-point
    $GDIP_DASHSTYLEDASHDOTDOT - Une ligne qui alterne tiret-point-point
    $GDIP_DASHSTYLECUSTOM - Un style de ligne personnalisé définie par l'utilisateur

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_PenGetDashStyle

Voir aussi

Cherchez GdipSetPenDashStyle dans la Library MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hPen

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Crée des ressources
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 8)
    _GDIPlus_PenSetDashStyle($hPen, $GDIP_DASHSTYLEDASHDOT)

    ; Affiche le style de crayon
    MsgBox($MB_SYSTEMMODAL, "Information", "Pen dash style: " & _GDIPlus_PenGetDashStyle($hPen))

    ; Dessine une ligne
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example