UDF > GDIPlus > PathGradientBrush >

_GDIPlus_PathBrushSetLinearBlend

Définit la manière de mélanger les couleurs d'un pinceau à couleurs dégradées de tracé pour créer un mélange personnalisé selon sur une courbe en triangle

#include <GDIPlus.au3>
_GDIPlus_PathBrushSetLinearBlend ( $hPathGradientBrush, $fFocus [, $fScale = 1] )

Paramètres

$hPathGradientBrush Handle de l'objet PathGradientBrush
$fFocus Nombre dans la gamme de 0,0 à 1,0 qui spécifie où la couleur de centre sera à sa plus haute intensité
$fScale [optionnel] Nombre compris entre 0.0 à 1.0 qui indique le pourcentage (/100) de la couleur de fin que le dégradé atteindra progressivement par fusion avec la couleur de début du dégradé. La valeur par défaut est 1, ce qui signifie que la couleur de fin de zone est en pleine intensité

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

En relation

_GDIPlus_PathBrushSetSigmaBlend

Voir aussi

Consultez GdipSetPathGradientLinearBlend dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("GDI+", 200, 180)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGraphics, 0xFF000000)

    Local $hPath = _GDIPlus_PathCreate()
    _GDIPlus_PathAddEllipse($hPath, 10, 10, 180, 160)

    Local $hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
    _GDIPlus_PathBrushSetCenterPoint($hBrush, 100, 90)
    _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFF0000FF)
    _GDIPlus_PathBrushSetLinearBlend($hBrush, 0.25, 0.75)
    _GDIPlus_GraphicsFillPath($hGraphics, $hPath, $hBrush)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example