UDF > GDIPlus > PathGradientBrush >

_GDIPlus_PathBrushGetFocusScales

Pour un pinceau à couleurs dégradées de tracé, obtient les facteurs d'échelles pour l'atténuation du dégradé à partir du point focus

#include <GDIPlus.au3>
_GDIPlus_PathBrushGetFocusScales ( $hPathGradientBrush )

Paramètre

$hPathGradientBrush Handle de l'objet PathGradientBrush

Valeur de retour

Succès: Retourne un tableau contenant les échelles du point de focus:
    [0] - échelle du focus suivant X
    [1] - échelle de focus suivant Y
Échec: Définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_PathBrushSetFocusScales

Voir aussi

Consultez GdipGetPathGradientFocusScales dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("GDI+", 200, 180, -1, 50)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGraphics, 0xFF000000)

    Local $hPath = _GDIPlus_PathCreate()
    _GDIPlus_PathAddEllipse($hPath, 10, 10, 180, 160)

    Local $hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
    _GDIPlus_PathBrushSetFocusScales($hBrush, 0.25, 0.75)
    _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFFFFFF00)
    _GDIPlus_PathBrushSetCenterPoint($hBrush, 90, 80)
    _GDIPlus_PathBrushSetSurroundColor($hBrush, 0xFF0000FF)
    _GDIPlus_PathBrushSetGammaCorrection($hBrush, True)
    _GDIPlus_GraphicsFillPath($hGraphics, $hPath, $hBrush)

    Local $aValue = _GDIPlus_PathBrushGetFocusScales($hBrush)
    MsgBox($MB_SYSTEMMODAL, "", "X focus scale: " & $aValue[0] & @CRLF & "Y focus scale: " & $aValue[1])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example