UDF > GDIPlus > LineBrush >

_GDIPlus_LineBrushSetTransform

Pour un pinceau à dégradé linéaire existant, définit la matrice de transformation des couleurs

#include <GDIPlus.au3>
_GDIPlus_LineBrushSetTransform ( $hLineGradientBrush, $hMatrix )

Paramètres

$hLineGradientBrush Handle de l'objet LinearGradientBrush
$hMatrix Handle de l'objet Matrix qui spécifie la matrice de transformation

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

Voir aussi

Consultez GdipSetLineTransform dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hBrush, $hMatrix

    $hGUI = GUICreate("GDI+", 420, 420)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsClear($hGraphic, 0xFFFFFFFF)

    $hBrush = _GDIPlus_LineBrushCreate(10, 10, 410, 410, 0xFF000000, 0xFFFFFFFF, 3)
    _GDIPlus_LineBrushSetSigmaBlend($hBrush, 1)

    $hMatrix = _GDIPlus_MatrixCreate()
    _GDIPlus_MatrixRotate($hMatrix, 45)

    _GDIPlus_LineBrushSetTransform($hBrush, $hMatrix)

    _GDIPlus_GraphicsFillRect($hGraphic, 10, 10, 400, 400, $hBrush)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_MatrixDispose($hMatrix)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example