UDF > GDIPlus > LineBrush >

_GDIPlus_LineBrushSetPresetBlend

Pour un pinceau à dégradé linéaire existant, définit les couleurs à mélanger et les positions correspondantes

#include <GDIPlus.au3>
_GDIPlus_LineBrushSetPresetBlend ( $hLineGradientBrush, $aInterpolations )

Paramètres

$hLineGradientBrush Handle de l'objet LinearGradientBrush
$aInterpolations Tableau de couleurs à mélanger et positions correspondantes:
    [0][0] - Le nombre de paires (couleur,position), doit être d'au moins 2
    [1][0] - Couleur 1
    [1][1] - Position 1
    [2][0] - Couleur 2
    [2][1] - Position 2
    [n][0] - Couleur n
    [n][1] - Position n

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

Remarque

Dans le paramètre $aInterpolations les éléments Couleur sont les codes des couleurs à fusionner et les éléments Position sont des pourcentages (/100) à partir de la ligne de début.

Voir aussi

Consultez GdipSetLinePresetBlend dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    _GDIPlus_Startup() ; Initialise GDI+
    Local Const $iWidth = 600, $iHeight = 300, $iBgColor = 0x303030 ; $iBGColor est au format RRGGBB

    Local $hGUI = GUICreate("GDI+ example", $iWidth, $iHeight) ; Crée une fenêtre de test
    GUISetBkColor($iBgColor, $hGUI) ; Définit la couleur de fond de la GUI
    GUISetState(@SW_SHOW)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet Graphics à partir du handle de la fenêtre
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Définit pour l'objet graphique la qualité de rendu antialiasing

    Local $hBrush = _GDIPlus_LineBrushCreate(0, 0, 580, 280, 0, 0, 1) ; Crée un pinceau

    Local $aInterpolations[5][2] ; Définit les couleurs interpolées et les emplacements
    $aInterpolations[0][0] = 4
    $aInterpolations[1][0] = 0xFFFF0000 ; Rouge
    $aInterpolations[1][1] = 0 ; 0 % à partir de la gauche
    $aInterpolations[2][0] = 0xFF00FF00 ; Vert
    $aInterpolations[2][1] = 0.3 ; Jusqu'à 30 % à partir de la gauche
    $aInterpolations[3][0] = 0xFF0000FF ; Bleu
    $aInterpolations[3][1] = 0.7 ; Jusqu'à 70% à partir de la gauche
    $aInterpolations[4][0] = 0xFFFFFF00 ; Jaune
    $aInterpolations[4][1] = 1 ; Jusqu'à 100% à partir de la gauche

    _GDIPlus_LineBrushSetPresetBlend($hBrush, $aInterpolations) ; Définir les couleurs et les emplacements de pinceau de dégradé linéaire

    _GDIPlus_GraphicsFillRect($hGraphics, 10, 10, 580, 280, $hBrush) ; Dessine le bitmap à l'écran

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources GDI+
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example