UDF > GDIPlus > LineBrush >

_GDIPlus_LineBrushSetLinearBlend

Pour un pinceau à dégradé linéaire existant, définit la manière de fusionner les deux couleurs selon une courbe en triangle.

#include <GDIPlus.au3>
_GDIPlus_LineBrushSetLinearBlend ( $hLineGradientBrush, $fFocus [, $fScale = 1] )

Paramètres

$hLineGradientBrush Handle de l'objet LinearGradientBrush
$fFocus Nombre compris entre 0.0 et 1.0 qui spécifie la zone dans laquelle la couleur est progressivement dégradée de la couleur de début à un pourcentage de la couleur de fin
$fScale [optionnel] Nombre compris entre 0.0 à 1.0 qui indique le pourcentage (/100) de la couleur de fin que le dégradé atteindra progressivement par fusion avec la couleur de début du dégradé. La valeur par défaut est 1, ce qui signifie que la couleur de fin de zone est en pleine intensité

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

En relation

_GDIPlus_LineBrushSetSigmaBlend

Voir aussi

Consultez GdipSetLineLinearBlend dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hBrush

    $hGUI = GUICreate("GDI+", 400, 400)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsClear($hGraphic, 0xFFFFFFFF)

    $hBrush = _GDIPlus_LineBrushCreate(10, 10, 390, 390, 0xFF000000, 0xFFFFFFFF)

    _GDIPlus_LineBrushSetLinearBlend($hBrush, 0.5)

    _GDIPlus_GraphicsFillRect($hGraphic, 10, 10, 380, 380, $hBrush)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example