#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    _GDIPlus_Startup() ; Initialise GDI+
    Local Const $iWidth = 600, $iHeight = 600, $iBgColor = 0x303030 ; $iBGColor est au format RRGGBB

    Local $hGUI = GUICreate("GDI+ example", $iWidth, $iHeight) ; Crée une fenêtre de test
    GUISetBkColor($iBgColor, $hGUI) ; Définit la couleur de fond de la GUI
    GUISetState(@SW_SHOW)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet Graphics à partir du handle de la fenêtre
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Définit pour l'objet graphique la qualité de rendu antialiasing
    Local $hBrush = _GDIPlus_LineBrushCreate(0, 0, 280, 570, 0xFFFFFF00, 0xFF4020FF, 1) ; Crée un pinceau à dégradé linéaire renversé

    Local $aBlends[5][2]
    $aBlends[0][0] = 4 ; Utilise 4 facteurs et 4 emplacements
    $aBlends[1][0] = 0 ; Facteur
    $aBlends[1][1] = 0 ; Emplacement
    $aBlends[2][0] = 1 ; Le pourcentage du mélange est de 100% (le dégradé du rouge au vert est  progressivement complété dans seulement 20% à partir de la gauche)
    $aBlends[2][1] = 0.2 ; Le pourcentage de la distance de la frontière gauche du pinceau est de 20%
    $aBlends[3][0] = 0 ; Le pourcentage de mélange est de 0% (le dégradé du vert au rouge passe progressivement de 20% à 70 % à partir la gauche)
    $aBlends[3][1] = 0.7 ; Le pourcentage de la distance de la frontière gauche du pinceau est de 70%
    $aBlends[4][0] = 1 ; Le pourcentage de mélange est de 100% (le dégradé du rouge au vert est progressivement complété de 70% à 100 % à partir de la gauche
    $aBlends[4][1] = 1 ; Le pourcentage de la distance de la frontière gauche du pinceau est à 100%

    _GDIPlus_LineBrushSetBlend($hBrush, $aBlends); Définit les emplacements de couleurs de pinceau de dégradé linéaire et les facteurs

    _GDIPlus_GraphicsFillEllipse($hGraphics, 100, 50, 380, 500, $hBrush) ; Dessine l'œuf

    Sleep(2000)

    _GDIPlus_GraphicsClear($hGraphics, 0xFF000000 + $iBgColor) ; Efface le bitmap
    _GDIPlus_LineBrushSetColors($hBrush, 0xFFFFFFFF, 0xFF000000) ; Change les valeurs des couleurs en niveaux de gris

    _GDIPlus_GraphicsFillEllipse($hGraphics, 100, 50, 380, 500, $hBrush) ; Dessine de nouveau l'œuf

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources GDI+
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example