UDF > GDIPlus > LineBrush >

_GDIPlus_LineBrushCreateFromRect

Crée un pinceau à dégradé linéaire sur la base d'un rectangle, des couleurs de début et de fin, et de l'orientation

#include <GDIPlus.au3>
_GDIPlus_LineBrushCreateFromRect ( $tRECTF, $iARGBClr1, $iARGBClr2 [, $iGradientMode = 0 [, $iWrapMode = 0]] )

Paramètres

$tRectF Structure $tagGDIPRECTF qui spécifie les points de début et de fin du dégradé
$iARGBClr1 Composantes Alpha, Rouge, Vert et Bleu de la couleur de début de la ligne
$iARGBClr2 Composantes Alpha, Rouge, Vert et Bleu de la couleur de fin de la ligne
$iGradientMode [optionnel] La direction du dégradé:
    0 - Direction horizontale de la gauche de l'écran vers la droite de l'écran,
    1 - Direction verticale depuis le haut de l'écran vers le bas de l'écran
    2 - Direction vers l'avant en diagonale à partir du coin supérieur gauche au coin inférieur droit de l'écran
    3 - Direction vers l'arrière en diagonale à partir du coin supérieur droit vers le coin inférieur gauche de l'écran
$iWrapMode [optionnel] Indique comment un dégradé est disposé en mosaïque lorsqu'il est plus petit que la zone à remplir:
    0 - Dispose le dégradé en mosaïque, sans symétrie
    1 - Retourne le dégradé horizontalement, puis le dispose en mosaïque
    2 - Retourne le dégradé verticalement, puis le dispose en mosaïque
    3 - Retourne le dégradé horizontalement et verticalement, puis le dispose en mosaïque
    4 - Le dégradé n'est pas disposé en mosaïque

Valeur de retour

Succès: Retourne le handle du nouvel objet LinearGradientBrush.
Échec: Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarque

Lorsque vous en avez terminé avec l'objet, appelez _GDIPlus_BrushDispose() pour libérer les ressources de l'objet.

En relation

_GDIPlus_BrushDispose

Voir aussi

Consultez GdipCreateLineBrushFromRect dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hBrush, $tRectF

    $hGUI = GUICreate("GDI+", 420, 320)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsClear($hGraphic, 0xFF000000)

    $tRectF = _GDIPlus_RectFCreate(10, 10, 400, 300)
    $hBrush = _GDIPlus_LineBrushCreateFromRect($tRectF, 0xFF000000, 0xFFFFFFFF, 2)
    _GDIPlus_LineBrushSetSigmaBlend($hBrush, 1)

    _GDIPlus_GraphicsFillRect($hGraphic, 10, 10, 400, 300, $hBrush)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example