UDF > GDIPlus > Image >

_GDIPlus_ImageRotateFlip

Applique des rotations et des symétries à une image

#include <GDIPlus.au3>
_GDIPlus_ImageRotateFlip ( $hImage, $iRotateFlipType )

Paramètres

$hImage Handle de l'objet Image
$iRotateFlipType Type de rotation et symétrie:
    0 - Pas de rotation et pas de symétrie (rotation de 180 degrés, symétrie horizontale puis symétrie verticale)
    1 - Une rotation de 90 degrés sans symétrie (rotation de 270 degrés, symétrie horizontale puis symétrie verticale)
    2 - Une rotation de 180 degrés sans symétrie (pas de rotation, une symétrie horizontale suivie d'une symétrie verticale)
    3 - Une rotation de 270 degrés sans symétrie (rotation de 90 degrés, symétrie horizontale puis symétrie verticale)
    4 - Pas de rotation et une symétrie horizontale (rotation de 180 degrés suivie d'une symétrie verticale)
    5 - Une rotation de 90 degrés suivie d'une symétrie horizontale (une rotation de 270 degrés suivie d'une symétrie verticale)
    6 - Une rotation de 180 degrés suivie d'une symétrie horizontale (pas de rotation et une symétrie verticale)
    7 - Une rotation de 270 degrés suivie d'une symétrie horizontale (rotation de 90 degrés suivie d'une symétrie verticale )

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

Voir aussi

Consultez GdipImageRotateFlip dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    _GDIPlus_Startup()
    Local Const $iW = @DesktopWidth / 2, $iH = @DesktopHeight / 2

    Local $hHBmp = _ScreenCapture_Capture("", 0, 0, @DesktopWidth / 2, @DesktopHeight / 2) ; Crée un bitmap GDI en capturant un quart de bureau
    Local $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hHBmp) ; Convertit le bitmap GDI en GDI+
    _WinAPI_DeleteObject($hHBmp) ; Libère la ressource du bitmap GDI car elle n'est plus utile
    _GDIPlus_ImageRotateFlip($hBitmap, 1) ; Fait pivoter l'image de 90 degrés sans retournement

    Local $hGUI = GUICreate("GDI+ test", $iH, $iW, -1, -1) ; Crée une GUI de test pour afficher l'image pivotée
    GUISetState(@SW_SHOW)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet Graphics à partir du handle de la fenêtre
    _GDIPlus_GraphicsDrawImage($hGraphics, $hBitmap, 0, 0) ; Affiche l'image pivotée

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE 

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example