UDF > GDIPlus > Image >

_GDIPlus_ImageGetHorizontalResolution

Retourne la résolution horizontale en DPI (pixels par pouce) d'une image

#include <GDIPlus.au3>
_GDIPlus_ImageGetHorizontalResolution ( $hImage )

Paramètre

$hImage Handle de l'objet image

Valeur de retour

Succès: Retourne un nombre entier de DPI (pixels par pouce).
Échec: Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).
@error: 10 - Le DPI ne peut pas être récupéré.
11 - Le handle de l'image est invalide.

En relation

_GDIPlus_ImageGetVerticalResolution

Voir aussi

Consultez GdipGetImageHorizontalResolution dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hBitmap, $hImage

    ; Crée une GUI
    GUICreate("GDI+", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Initialise la bibliothèque GDI+
    _GDIPlus_Startup()

    ; Capture un bitmap 32 bits
    $hBitmap = _ScreenCapture_Capture("")
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)

    ; Affiche la résolution horizontale en DPI (points par pouce) de l'image
    MemoWrite("HorizontalResolution DPI : " & _GDIPlus_ImageGetHorizontalResolution($hImage)); 

    ; Nettoie les ressources
    _GDIPlus_ImageDispose($hImage)
    _WinAPI_DeleteObject($hBitmap)

    ; Arrête la bibliothèque GDI+
    _GDIPlus_Shutdown()

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage = '')
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite