Fonction _GDIPlus_HatchBrushCreate

Crée un objet HatchBrush (pinceau à hachures) à partir d'un style de hachures, d'une couleur de premier plan (lignes), et d'une couleur de fond (entre les lignes)

#include <GDIPlus.au3>
_GDIPlus_HatchBrushCreate ( [$iHatchStyle = 0 [, $iARGBForeground = 0xFFFFFFFF [, $iARGBBackground = 0xFFFFFFFF]]] )

Paramètres

Valeur de retour

Remarques

Les constantes des motifs de hachures sont déclarées dans GDIPlusConstants.au3, celles qui commencent par $GDIP_HATCHSTYLE_*.
Lorsque vous en avez terminé avec l'objet HatchBrush, appelez _GDIPlus_BrushDispose() pour libérer les ressources.

En relation

Voir aussi

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hBrush, $iX, $iY

    ; Crée une GUI
    Local $hGUI = GUICreate("GDI+", 810, 610)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    Local $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet graphique à partir du handle de la fenêtre

    For $i = 0 To 52
        $iX = 10 + Mod($i, 10) * 80
        $iY = 30 + Floor($i / 10) * 100
        _GDIPlus_GraphicsDrawString($hGraphic, $i, $iX, $iY - 16)

        $hBrush = _GDIPlus_HatchBrushCreate($i, 0xFF00FF00, 0xFF0000FF)
        _GDIPlus_GraphicsFillRect($hGraphic, $iX, $iY, 70, 70, $hBrush)

        _GDIPlus_BrushDispose($hBrush)
    Next

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example

Succès:	Retourne le handle d'un nouvel objet HatchBrush.
Échec:	Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

$iHatchStyle	[optionnel] Motif de hachures à utiliser, voir Remarques. Par défaut $GDIP_HATCHSTYLE_HORIZONTAL (0).
$iARGBForeground	[optionnel] Composantes Alpha, Rouge, Vert et Bleu des lignes de hachures
$iARGBBackground	[optionnel] Composantes Alpha, Rouge, Vert et Bleu du fond