UDF > GDIPlus > GraphicsCoders >

_GDIPlus_EncodersGetSize

Obtient la taille totale de la structure qui est retournée par _GDIPlus_GetImageEncoders

#include <GDIPlus.au3>
_GDIPlus_EncodersGetSize ( )

Valeur de retour

Succès: Retourne la taille totale en octets.
Échec: Retourne -1 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_EncodersGetCount

Voir aussi

Consultez GdipGetImageEncodersSize dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    ; Crée GUI
    GUICreate("GDI+", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Initialise la bibliothèque GDI+
    _GDIPlus_Startup()

    ; Affiche le nombre de décodeurs/encodeurs
    MemoWrite("Decoder count : " & _GDIPlus_DecodersGetCount()); 
    MemoWrite("Decoder size .: " & _GDIPlus_DecodersGetSize()); 
    MemoWrite("Encoder count : " & _GDIPlus_EncodersGetCount()); 
    MemoWrite("Encoder size .: " & _GDIPlus_EncodersGetSize()); 

    ; Arrête la bibliothèque GDI+
    _GDIPlus_Shutdown()

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage = '')
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite