UDF > FTPEx >


_FTP_FileGetSize

Obtient la taille d'un fichier sur le serveur FTP

#include <FTPEx.au3>
_FTP_FileGetSize ( $hFTPSession, $sFileName )

Paramètres

$hFTPSession Handle retourné par _FTP_Connect().
$sFileName Le nom du fichier.

Valeur de retour

Succès: Retourne la taille du fichier, de type uint64.
Échec: Définit @error <> 0.

En relation

_FTP_Connect

Voir aussi

Consultez FtpGetFileSize dans la librairie MSDN.

Exemple

#include <FTPEx.au3>

Local $sServer = 'ftp.csx.cam.ac.uk'
Local $sUsername = ''
Local $sPass = ''

Local $hOpen = _FTP_Open('MyFTP Control')
Local $hConn = _FTP_Connect($hOpen, $sServer, $sUsername, $sPass)

Local $h_Handle
Local $aFile = _FTP_FindFileFirst($hConn, "/pub/software/programming/pcre/", $h_Handle)
ConsoleWrite('$sFilename = ' & $aFile[10] & 'attribute = ' & $aFile[1] & ' -> Error code: ' & @error & ' extended: ' & @extended & @CRLF)

Local $sDirset = _FTP_DirSetCurrent($hConn, "/pub/software/programming/pcre/")
ConsoleWrite('$sDirset = ' & $sDirset & ' -> Error code: ' & @error & ' extended: ' & @extended & @CRLF)

Local $iFileSize = _FTP_FileGetSize($hConn, $aFile[10])
ConsoleWrite('$sFilename = ' & $aFile[10] & 'size = ' & $iFileSize & ' -> Error code: ' & @error & ' extended: ' & @extended & @CRLF)

Local $iErr, $sMessage
$iFileSize = _FTP_GetLastResponseInfo($iErr, $sMessage) ; error = Contrib : pas un fichier régulier
ConsoleWrite('$sMessage = ' & $sMessage & 'err = ' & $iErr & ' -> Error code: ' & @error & ' extended: ' & @extended & @CRLF)

$aFile = _FTP_FindFileNext($h_Handle)
ConsoleWrite('$sFilenameNext1 = ' & $aFile[10] & 'attribute = ' & $aFile[1] & ' -> Error code: ' & @error & ' extended: ' & @extended & @CRLF)

$iFileSize = _FTP_FileGetSize($hConn, $aFile[10])
ConsoleWrite('$sFilenameNext1 = ' & $aFile[10] & 'size = ' & $iFileSize & ' -> Error code: ' & @error & ' extended: ' & @extended & @CRLF)

$iFileSize = _FTP_GetLastResponseInfo($iErr, $sMessage) ; pas d'erreur
ConsoleWrite('$sMessage = ' & $sMessage & 'err = ' & $iErr & ' -> Error code: ' & @error & ' extended: ' & @extended & @CRLF)

Local $iFindClose = _FTP_FindFileClose($h_Handle)

Local $iFtpc = _FTP_Close($hConn)
Local $iFtpo = _FTP_Close($hOpen)