UDF > FTPEx >

_FTP_ListToArrayEx

Obtiet le nom, la taille, les attributs et la date et l'heure des fichiers/répertoires du répertoire courant distant

#include <FTPEx.au3>
_FTP_ListToArrayEx ( $hFTPSession [, $iReturnType = 0 [, $iFlags = $INTERNET_FLAG_NO_CACHE_WRITE [, $iFmt = 1 [, $iContext = 0]]]] )

Paramètres

$hFTPSession Handle retourné par _FTP_Connect().
$iReturntype [optionnel] 0 = A la fois les fichiers et les répertoires, 1 = Répertoires, 2 = Fichiers.
$iFlags [optionnel] Par défaut = $INTERNET_FLAG_NO_CACHE_WRITE. Voir _FTP_FindFileFirst().
$iFmt [optionnel] Type des chaînes de date:
    1 = aaaa/mm/jj
    0 = mm/jj/aaaa
$iContext [optionnel] Une variable qui contient la valeur définie par l'application qui associe cette recherche à des données de l'application.
Ce n'est utilisée que si l'application a déjà appelé _FTP_SetStatusCallback() pour mettre en place le statut d'une fonction de rappel.

Valeur de retour

Succès: Retourne un tableau 2D:
    $Array[0][0] = nombre d'entrées trouvées
    ...
    $Array[n][0] Nom du fichier
    $Array[n][1] Taille du fichier
    $Array[n][2] Attributs du fichier
    $Array[n][3] Date de modification du fichier
    $Array[n][4] Date de création du fichier
    $Array[n][5] Date d'accès au fichier
Échec: Retourne $Array[0][0] = 0.

En relation

_FTP_Connect, _FTP_SetStatusCallback, _FTP_ListToArray, _FTP_ListToArray2D

Exemple

#include <Array.au3>
#include <FTPEx.au3>
#include <MsgBoxConstants.au3>

Local $sServer = 'ftp.csx.cam.ac.uk1'
Local $sUsername = ''
Local $sPass = ''

Local $hOpen = _FTP_Open('MyFTP Control', 0)
If Not @error Then
    ; Passive permet une meilleure protection des réponses FTP
    Local $hConn = _FTP_Connect($hOpen, $sServer, $sUsername, $sPass)
    If Not @error Then
        Local $aFile = _FTP_ListToArrayEx($hConn, 0)
        If Not @error Then
            _ArrayDisplay($aFile)
        Else
            MsgBox($MB_SYSTEMMODAL, "Error", '_FTP_ListToArrayEx($Conn, 0)' & @CRLF & _
                    '@error = ' & @error & ' @extended = ' & @extended)
        EndIf
        Local $iFtpc = _FTP_Close($hConn)
    Else
        MsgBox($MB_SYSTEMMODAL, "Error", '_FTP_Connect($Open, ' & $sServer & ', ' & $sUsername & ', ' & $sPass & ')' & @CRLF & _
                '@error = ' & @error & ' @extended = ' & @extended)
    EndIf

    Local $iFtpo = _FTP_Close($hOpen)
Else
    MsgBox($MB_SYSTEMMODAL, "Error", "_FTP_Open('MyFTP Control')" & @CRLF & _
            '@error = ' & @error & ' @extended = ' & @extended)
EndIf