UDF > Date >


_Date_Time_SystemTimeToArray

Décode une date/heure système en un tableau

#include <Date.au3>
_Date_Time_SystemTimeToArray ( ByRef $tSYSTEMTIME )

Paramètre

$tSYSTEMTIME Structure $tagSYSTEMTIME

Valeur de retour

Retourne un tableau (array) au format suivant :
[0] - Mois
[1] - Jour
[2] - Année
[3] - Heure
[4] - Minutes
[5] - Secondes
[6] - Millisecondes
[7] - Jour de la semaine

En relation

$tagSYSTEMTIME

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tTime, $aTime

    ; Crée la GUI
    GUICreate("Temps", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient l'heure actuelle du système
    $tTime = _Date_Time_GetSystemTime()
    $aTime = _Date_Time_SystemTimeToArray($tTime)
    MemoWrite("Mois ............... : " & $aTime[0])
    MemoWrite("Jour ............... : " & $aTime[1])
    MemoWrite("Année .............. : " & $aTime[2])
    MemoWrite("Heure .............. : " & $aTime[3])
    MemoWrite("Minute ............. : " & $aTime[4])
    MemoWrite("Seconde ............ : " & $aTime[5])
    MemoWrite("Millisecondes ...... : " & $aTime[6])
    MemoWrite("Jour de la semaine . : " & $aTime[7])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite