UDF > Date >

_Date_Time_GetSystemTimes

Obtient les informations d'inactivité du système

#include <Date.au3>
_Date_Time_GetSystemTimes ( )

Valeur de retour

Retourne un tableau (array) au format suivant:
   [0] - Structure $tagFILETIME avec le temps d'inactivité total du système
   [1] - Structure $tagFILETIME avec le temps d'inactivité total du système en mode noyau
   [2] - Structure $tagFILETIME avec le temps d'inactivité total du système en mode utilisateur

En relation

$tagFILETIME

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $aTime

    ; Crée la GUI
    GUICreate("Temps", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Récupère le temps système
    $aTime = _Date_Time_GetSystemTimes()

    MemoWrite("Temps d'inactivité... : " & _Date_Time_FileTimeToStr($aTime[0]))
    MemoWrite("Temps système . : " & _Date_Time_FileTimeToStr($aTime[1]))
    MemoWrite("Temps utilisateur... : " & _Date_Time_FileTimeToStr($aTime[2]))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite