Functions > Tray >


TraySetClick

Définit le mode clic de l'icône de la zone de notification - quel clic de souris affiche un menu.

TraySetClick ( flag )

Paramètre

flag 0 = Le menu de la zone de notification ne sera jamais affiché par un clic de souris
1 = En appuyant sur le bouton principal (gauche) de la souris
2 = En relâchant le bouton principal de la souris
4 = En double-cliquant sur le bouton principal de la souris
8 = En appuyant sur le bouton secondaire (droit) de la souris
16 = En relâchant le bouton secondaire de la souris
32 = En double-cliquant sur le bouton secondaire de la souris
64 = En survolant l'icône

Valeur de retour

Aucune.

Remarques

Ces flags ne sont PAS des valeurs d'événement de la zone de notification!
La valeur par défaut est "9" - en appuyant sur le bouton principal ou secondaire de la souris vous affichez le menu.

En relation

TraySetOnEvent

Exemple

#NoTrayIcon
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <TrayConstants.au3> ; Pour la constante $TRAY_ICONSTATE_SHOW.

; Les items du menu, par défaut, ne seront pas affichés et 
; les items ne seront pas cochés lorsqu'ils seront sélectionnés. 
; Ce sont les options 1 et 2 de TrayMenuMode.
Opt("TrayMenuMode", 3)

Example()

Func Example()
    Local $idAbout = TrayCreateItem("About")
    TrayCreateItem("") ; Crée une ligne de séparation.

    Local $idExit = TrayCreateItem("Exit")

    TraySetState($TRAY_ICONSTATE_SHOW) ; Affiche le menu de la barre.
    TraySetClick(64) ; Affiche le menu de la zone de notification lorsque la souris survole l'icône.

    Local $iASlash, $sPath, $iMsg = TrayGetMsg()
    While $iMsg <> $idExit
        If $iMsg = $idAbout Then
            ; Affiche une boîte de message à propos de la version et 
            ; du chemin d'installation de l'exécutable AutoIt.

            ; Recherche de droite à gauche l'antislash qui marque la fin du chemin
            $iASlash = StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1)
            ; Extrait le chemin seul, sans le nom, ni '\'
            $sPath = StringLeft(@AutoItExe, $iASlash - 1)

            MsgBox($MB_SYSTEMMODAL, "", "Exemple de menu dans la zone de notification." & @CRLF & @CRLF & _
                "Version: " & @AutoItVersion & @CRLF & _
                "Chemin d'installation: " & $sPath) 
        EndIf

        $iMsg = TrayGetMsg()
    WEnd
EndFunc   ;==>Example